¿ Quieres imprimir esta página ? Volver a la página principal de Recursos iSeries AS400 ¿ Necesitas ayuda ? En pruebas
Recursos iSeries AS400. Compartiendo generamos conocimiento
Novedades en Recursos iSeries AS400
Últimas noticias del iSeries AS400
Mover ventanas con el raton

Categoría : Programación
Autor : Luis Gómez
Título : Mover ventanas con el raton


Descripción del truco:
Este truco permite mover la ventana a varias partes de la pantalla con el raton

*** PANTALLA ******

     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT
     A                                      CA03(03)
     A          R @RF01
     A                                      CA12(12)
     A                                      RTNCSRLOC(*MOUSE &FIL1 &COL1 &FIL2 -
     A                                      &COL2)
     A                                      WINDOW(&FIL &COL 5 40 *NOMSGLIN *NO-
     A                                      RSTCSR)
     A                                      WDWBORDER((*DSPATR RI) (*CHAR '    -
     A                                          '))
     A  12                                  RMVWDW
     A                                      WDWTITLE((*TEXT 'F3 = TERMINAR') *C-
     A                                      ENTER *BOTTOM)
     A                                      MOUBTN(*ULP CA12)
     A            FIL            2S 0P
     A            COL            3S 0P
     A            FIL1           3S 0H
     A            COL1           3S 0H
     A            FIL2           3S 0H
     A            COL2           3S 0H
     A                                  2  3'Haga click con el mouse donde quie-
     A                                      re'
     A                                  3 13'ubicar la ventana'
     A*
     A          R @ASSUME
     A                                      ASSUME
     A            FLD001         1   O 24  4

***** RPG ******

      *******************************************************************
      *                                                                 *
      *   PROGRAMA ...: BRCD028A.                                       *
      *   DESCRIPCION : Cambiar la ubicación de la ventana por          *
      *                 medio del mouse.                                *
      *                                                                 *
      *-----------------------------------------------------------------*
      *   SECCION DE ACTUALIZACION                                      *
      *-----------------------------------------------------------------*
      * Fecha       |  Modificación                      | Responsable  *
      *-----------------------------------------------------------------*
      *     /  /                                                        *
      *                                                                 *
      *******************************************************************

     fbrcd028da cf   e             workstn

      *-----------------------------------------------------------------*
      *   Principal                                                     *
      *-----------------------------------------------------------------*

     c                   dow       ' ' = ' '

      *  Mostrar la pantalla

     c                   exfmt     @rf01

      *  Terminar el proceso

     c                   if        (*in03)
     c                   leave
     c                   endif

      *  Verificar si se hizo click con el mouse

     c                   if        (*in12)

      *  Mover la ventana a la posición del cursor

     c                   eval      fil = fil1
     c                   eval      col = col1

      *  Verificar que la posición donde se hizo click este dentro
      *  de la pantalla (24x80)

     c                   if        col > 37
     c                   eval      col = 37
     c                   endif
     c                   if        fil > 17
     c                   eval      fil = 17
     c                   endif

     c                   endif

     c                   enddo

      *  Fin del programa

     c                   eval      *inlr = *on

      *-----------------------------------------------------------------*
      *   Subrutina de inicialización                                   *
      *-----------------------------------------------------------------*
     c     *inzsr        begsr

      *  Posición inicial de la ventana

     c                   eval      fil = 7
     c                   eval      col = 10

     c                   endsr
                        

Ver código fuente DDS
Ver código fuente RPG
Fecha 11-11-2004

Tienes algún truco que quieras compartir con todos los profesionales de Recursos iSeries AS400?.Envianoslo y si resulta seleccionado te enviaremos un vale de Amazon por valor de 50$

Comentarios de usuarios

Nombre:
Mail:
Comentario:
 

Subir a la parte superior de la web

Dossiers técnicos iSeries y AS400
- Dossier de seguridad
- Alta disponibilidad.
¿Buscas trabajo ?
Inscríbete en nuestra lista laboral y recibirás las ofertas de trabajo en tu buzón de correo electrónico.
Nuestros links preferidos
- Tendencias tecnologías de la información
Expertos en materías relacionadas con las tecnologías de la información, nos dan su punto de vista sobre las tendencias actuales y futuras
- Los últimos anuncios sobre hardware-software para iSeries AS400 realizados por IBM
- Freeware. Software gratuito para el iSeries AS400
- Utilidades para el iSeries AS400 realizadas por profesionales
- Documentos. Trucos e ideas para resolver tus problemas
- Manuales. Los manuales y links más interesantes del iSeries AS400

  Links patrocinados
  •  
  •  

[ Soy nuevo |   Profesionales |   AS qué |   Empresas |    Foros |   Recomiéndanos |    Productos ]
 
Recursos iSeries AS400. Es una web de: PUBLICACIONES HELP400, S.L. CIF:B-60-202827 Gran Vía de les Corts Catalanes, núm. 715, Entresuelo – 3ª - Barcelona - Tel.+34.932.310.049